FunctionBlocks BasicMove MC_MoveLinearAbsoluteFB - ThorstenBrach/SRCI GitHub Wiki

MC_MoveLinearAbsoluteFB

📝 Description:

Move the TCP to an absolute cartesian position (linear interpolation).

⚙️ FB Variables:

VAR_INPUT
Parameter Data Type Default Value Description Required

InternalLogger

IMessageLogger

-

For internal usage only

-

ExternalLogger

IMessageLogger

-

For internal usage only

-

LogLevel

LogLevelEnum

-

For internal usage only

-

Name

STRING(20)

-

User defined command name

O

ExecMode

ExecutionMode

ExecutionMode.SEQUENCE_PRIMARY

Execution mode of the command

M

Priority

PriorityLevel

PriorityMode.NORMAL

Priority of the command

M

AbortingMode

AbortingMode

AbortingMode.BUFFER

Parameter which determines the behavior towards the previously sent and still active or buffered commands

M

SequenceFlag

SequenceFlag

SequenceFlag.PRIMARY_SEQUENCE

Defines the target sequence in which the command will be executed

M

Execute

BOOL

-

Start of the command at the rising edge

M

ParCmd

[MoveLinearAbsoluteParCmd]

-

Command specific parameter

M
VAR_IN_OUT
Parameter Data Type Default Value Description Required

AxesGroup

AxesGroup

-

Robot group assigned to the function

M
VAR_OUTPUT
Parameter Data Type Default Value Description Required

CommandData

RobotLibraryCommandDataFB

-

For internal usage only

-

ResponseData

RobotLibraryResponseDataFB

-

For internal usage only

-

Error

BOOL

-

Error occurred during execution. See ErrorID for details

M

ErrorID

WORD

-

Error ID as raw value for error diagnosis

M

ErrorIDEnum

RobotLibraryErrorIdEnum

-

Error ID as enumeration for error diagnosis

M

ErrorAddTxt

STRING(MAX_ADD_TEXT_LENGTH)

-

Additional error text information

M

WarningID

WORD

-

Warning ID as raw value for identifying warnings

M

WarningIDEnum

RobotLibraryWarningIdEnum

-

Warning ID as enumeration for identifying warning

M

InfoID

WORD

-

Info ID for as raw value for identifying additional information

M

InfoIDEnum

RobotLibraryInfoIdEnum

-

Info ID for as enumeration for identifying additional information

M

Done

BOOL

-

Command executed successfully

M

Busy

BOOL

-

Function block is being processed

M

CommmandBuffered

BOOL

-

Command was transferred to the robot-controller and confirmed

M

CommandAborted

BOOL

-

The command was aborted by another command.

M

CommandInterrupted

BOOL

-

TRUE, while command is interrupted during execution and can be continued

M

Active

BOOL

-

The command takes control of the motion of the according axis group

M

OutCmd

[MoveLinearAbsoluteOutCmd]

-

Command specific outputs

M

⚙️ FB Structures:

MoveLinearAbsoluteParCmd
Parameter Data Type Default Value Description Required

Position

RobotCartesianPosition

-

Absolute target coordinates in the selected coordinate system (see ToolNo and FrameNo)

M

VelocityRate

REAL

-

TCP velocity in % of nominal velocity
• <0%: Use default velocity (default)
• 0%: Use internal minimal velocity
• 100%: Use maximum reference velocity

M

AccelerationRate

REAL

-

Acceleration in % of nominal acceleration
• <0%: Use default acceleration (default)
• 0%: Use internal minimal acceleration
• 100%: Use maximum reference acceleration

M

DecelerationRate

REAL

-

Deceleration in % of nominal deceleration
• <0%: Use default deceleration (default)
• 0%: Use internal minimal deceleration
• 100%: Use maximum reference deceleration

M

JerkRate

REAL

-

Jerk in % of nominal jerk
• <0%: Use default jerk (default)
• 0%: Use internal minimal jerk
• 100%: Use maximum reference jerk

M

ToolNo

USINT

-

Tool index
• 0: Flange (default)
• 1..254: Tool frames

M

FrameNo

USINT

-

Frame index
• 0: WCS (default)
• 1..254: User frames

M

BlendingMode

BlendingMode

-

Defines the transition behavior at the end of the movement for blending into the next command

M

BlendingParameter

ARRAY[0..1] OF REAL

-

Additional parameters for blending mode, such as velocity limit (%) or blending radius

M

MoveTime

TIME

-

Used if >0 (default)
• Overrides velocity
• Defines the fixed duration to reach target
Error returned if duration cannot be held

M

OriMode

OriMode

-

Describes how the orientation axes (RX, RY, RZ) are interpolated during motion

M

ConfigMode

ArmConfigParameter

-

Defines how the configuration byte in the position is used

M

TurnMode

TurnMode

-

Defines how the TurnNumber byte in the position is used

M

Manipulation

BOOL

-

Set TRUE to allow superimposed manipulation of the movement

M

EmitterID

ARRAY[0..3] OF SINT

-

ID of Action triggered during command execution
• >0: Start Action (ListenerID match)
• <0: Stop Action (ListenerID match)
• 0: No trigger (default)

M
MoveLinearAbsoluteOutCmd
Parameter Data Type Default Value Description Required

Progress

REAL

-

Percentage of already traversed distance of the current job
• -1: Not supported

M

RemainingDistance

REAL

-

Distance-to-go of the current job
• -1: No valid value (command not yet active or unsupported)
• >0: Actual distance to target position
• 0: Target position reached

M

FollowID

DINT

-

Unique system-generated ID of the trigger function when called by the user

M

⏳ Timing Diagram:

Work in progress – more content coming soon.

📋 Examples:

Declaration 
VAR_GLOBAL
  /// Robot assignment of function
  AxesGroup          : AxesGroup;
  /// Robot Task
  RobotTask          : MC_RobotTaskFB;
  /// Move linear absolute
  MoveLinearAbsolute : MC_MoveLinearAbsoluteFB;
END_VAR
Call 
// call function block
MoveLinearAbsolute
(
  Name         := 'SRCI_Robot',
  ExecMode     := ExecutionMode.SEQUENCE_PRIMARY,
  Priority     := PriorityLevel.NORMAL,
  AbortingMode := AbortingModeEnum.BUFFER,
  SequenceFlag := SequenceFlag.PRIMARY_SEQUENCE,
  AxesGroup    := AxesGroup
);
Usage 
VAR_INPUT
  /// Start command execution
  Execute : BOOL;
  /// Command parameter
  ParCmd  : MoveLinearAbsoluteParCmd;
END_VAR

VAR_OUTPUT
  /// Error ID
  ErrorID     : DINT;
  /// Error addition text
  ErrorAddTxt : STRING;
  /// Command outputs
  OutCmd      : MoveLinearAbsoluteOutCmd;
END_VAR

VAR
  /// internal step counter
 _stepCmd    : DINT;
  /// internal timer for command
 _timerCmd   : TON;
  /// internal timeout for command
 _timeoutCmd : TIME := T#5S;
END_VAR
// forwarding command parameter(s)
MoveLinearAbsolute.ParCmd := ParCmd;
// forwarding command output(s)
OutCmd := MoveLinearAbsolute.OutCmd ;


CASE _stepCmd OF

  0: // start execution ?
     IF ( Execute )
     THEN
       // Reset request
       Execute := FALSE;
       // set timeout
       SetTimeout(PT := _timeoutCmd, rTimer := _timerCmd);
       // inc step counter
      _stepCmd := _stepCmd + 1;
     END_IF

  1: // Start Execution
     IF (( NOT MoveLinearAbsolute.Busy  ) AND
         ( NOT MoveLinearAbsolute.Error ))
     THEN
       // start execution
       MoveLinearAbsolute.Execute := TRUE;
       // set timeout
       SetTimeout(PT := _timeoutCmd, rTimer := _timerCmd);
       // inc step counter
      _stepCmd := _stepCmd + 1;
     ELSE
       // timeout exceeded ?
       IF (CheckTimeout(_timerCmd) = RobotLibraryConstants.OK)
       THEN
         ErrorID     := RobotLibraryErrorIdEnum.ERR_TIMEOUT_CMD;
         ErrorAddTxt := CONCAT('_stepCmd = ' , DINT_TO_STRING(_stepCmd));
       END_IF

       // Error occurred ?
       IF (MoveLinearAbsolute.Error)
       THEN
         ErrorID     := MoveLinearAbsolute.ErrorID;
         ErrorAddTxt := CONCAT('_stepCmd = ' , DINT_TO_STRING(_stepCmd));
       END_IF
     END_IF

  2: // Wait Execution done ?
     IF (( NOT MoveLinearAbsolute.Busy ) AND
         (     MoveLinearAbsolute.Done ))
     THEN
       // stop execution
       MoveLinearAbsolute.Execute := FALSE;
       // set timeout
       SetTimeout(PT := _timeoutCmd, rTimer := _timerCmd);
       // set step counter
      _stepCmd := 0;
     ELSE
       // timeout exceeded ?
       IF (CheckTimeout(_timerCmd) = RobotLibraryConstants.OK)
       THEN
         ErrorID     := RobotLibraryErrorIdEnum.ERR_TIMEOUT_CMD;
         ErrorAddTxt := CONCAT('_stepCmd = ' , DINT_TO_STRING(_stepCmd));
       END_IF

       // Error occurred ?
       IF (MoveLinearAbsolute.Error)
       THEN
         ErrorID     := MoveLinearAbsolute.ErrorID;
         ErrorAddTxt := CONCAT('_stepCmd = ' , DINT_TO_STRING(_stepCmd));
       END_IF
     END_IF

ELSE
  // invalid step
  ErrorID     := RobotLibraryErrorIdEnum.ERR_INVALID_STEP;
  ErrorAddTxt := CONCAT('_stepCmd = ' , DINT_TO_STRING(_stepCmd));
END_CASE

💡 Additional Information:

Work in progress – more content coming soon.

This project is made with ❤️ for automation ⚙️ and robotics 🤖

⚠️ **GitHub.com Fallback** ⚠️