ME3 ‐ Sending HTTP Requests - ME3Tweaks/LegendaryExplorer GitHub Wiki

Mass Effect 3 allows for sending HTTP requests through the SFXOnlineSubsystem class.

Below code shows an example class which sends a GET request to a local Node.JS Server.

Class NetworkingManager;

public static function NetworkingTest()
{
    local SFXOnlineJobHTTPRequest Job;
    local int iterator;
    
    log("JW_NETWORKING: - Begin Networking Test");
    Job = Class'SFXOnlineJobHTTPRequest'.static.CreateHTTPRequestJob();
    Job.mRequest.SetBaseURL("http://localhost:6060/player?PlayerId=John");
    Job.__OnJobComplete__Delegate = HTTPResult;
    Class'SFXOnlineSubsystem'.static.GetOnlineSubsystem().GetComponentJobQueue().AddJob(Job);
}
public static function HTTPResult(SFXOnlineHTTPRequest request)
{
    log(request.mResultBody);
}
public static function log(string Message)
{
    local SFXEngine Engine;
    local BioWorldInfo World;
    
    Engine = Class'SFXEngine'.static.GetSFXEngine();
    World = Engine.GetRealWorldInfo();
    World.GetALocalPlayerController().ClientMessage(Message);
}

In the above example I am setting the request parameter directly in the request string. However we can also use the AddParameter function in conjunction with GenerateParametersString on the SFXOnlineHTTPRequest class, like so.

public static function NetworkingTest()
{
    local SFXOnlineJobHTTPRequest Job;
    local int iterator;
    local string queryString;
    
    log("JW_NETWORKING: - Begin Networking Test");
    Job = Class'SFXOnlineJobHTTPRequest'.static.CreateHTTPRequestJob();
    Job.mRequest.SetBaseURL("http://localhost:6060/player");
    Job.mRequest.AddParameter("PlayerId", "John");
    queryString = Job.mRequest.GenerateParametersString();
    Job.mRequest.mURL $= queryString;
    Job.mRequest.mPost = TRUE;
    Job.__OnJobComplete__Delegate = HTTPResult;
    log("JW_NETWORKING: URL" $ Job.mRequest.mURL);
    Class'SFXOnlineSubsystem'.static.GetOnlineSubsystem().GetComponentJobQueue().AddJob(Job);
}

Unfortunately I have not yet figured out how to serialize the result, but just being able to retrieve some information from Third Party tools, opens a world of possibilities (I hope)!