Billboards 技术在Unity 中的几种使用方法 - yty/yty.github.io GitHub Wiki

关于billboard技术，原理就是计算出来一个始终朝向摄像机的面片，可以在CPU里计算，也可以在GPU里实现。应用的场合很多：

• 游戏角色的头顶文字，血条
• 场景的树，草
• 特效粒子片
• 3d场景里的2d角色

world space计算

思路：shader中传入面片的中心点的世界坐标，以及摄像机的right和up在world space的方向，中心点直接沿着right和up方向计算四个顶点的世界坐标，定点数据中包含了每个顶点的偏移信息。然后乘以ViewProjection矩阵，作为输出。 这里有个trick的地方，就是从object space 到world space是没有旋转的，只有偏移，所以摄像机在世界空间的right就是模型空间的right。MV的逆矩阵相当于View到Object的变换，转置是为了去列向量好取。

---

        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag

        struct appdata
        {
            float4 vertex : POSITION;
            float2 uv : TEXCOORD0;
            float2 vertexOffset : TEXCOORD1;
        };

        struct v2f
        {
            float2 uv : TEXCOORD0;
            float4 vertex : SV_POSITION;
        };

        sampler2D _MainTex;

        v2f vert (appdata v)
        {
            v2f o;

            //这里相当于取列向量

            float3 right = UNITY_MATRIX_IT_MV[0].xyz;
            float3 up = UNITY_MATRIX_IT_MV[1].xyz;

            v.vertex.xyz += v.vertexOffset.x * right + v.vertexOffset.y * up;
            o.vertex = mul(UNITY_MATRIX_VP, float4(v.vertex.xyz, 1.0));

            o.uv = v.uv;

            return o;
        }

        fixed4 frag (v2f i) : SV_Target
        {

            // sample the texture
            fixed4 col = tex2D(_MainTex, i.uv);
            return col;
        }
        ENDCG

unity c#中生成mesh的代码

---

    Vector3[] vertices = new Vector3[4]
    {
        worldPos,
        worldPos,
        worldPos,
        worldPos
    };

    int[] indices = new int[6]
    {
        0, 2, 1, 0, 3, 2
    };

    Vector2[] uvs = new Vector2[4]
    {
        new Vector2(0, 0),
        new Vector2(0, 1),
        new Vector2(1, 1),
        new Vector2(1, 0),
    };

    Vector2[] uv2s = new Vector2[4]
    {
        new Vector2(-0.5f, -0.5f),
        new Vector2(0.5f, -0.5f),
        new Vector2(0.5f, 0.5f),
        new Vector2(-0.5f, 0.5f),
    };

    meshFilter.mesh.vertices = vertices;
    meshFilter.mesh.triangles = indices;
    meshFilter.mesh.uv = uvs;
    meshFilter.mesh.uv2 = uv2s;

clip space计算

思路：还是传入中心点的世界坐标，以及4个顶点的偏移信息。把中心点转到 clip space，然后按照偏移信息缩放。这个适用的场合是面片不随距离摄像机的远近而缩放。

---

        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag

        struct appdata
        {
            float4 vertex : POSITION;
            float2 uv : TEXCOORD0;
            float2 vertexOffset : TEXCOORD1;
        };

        struct v2f
        {
            float2 uv : TEXCOORD0;
            float3 color : TEXCOORD1;
            float4 vertex : SV_POSITION;
        };

        sampler2D _MainTex;

        v2f vert (appdata v)
        {
            v2f o;

            o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
            o.vertex.xyz /= o.vertex.w;

            o.vertex.xy += v.vertexOffset.xy * float2(0.2, 0.05);
            o.vertex.w = 1;

            o.uv = v.uv;

            return o;
        }

        fixed4 frag (v2f i) : SV_Target
        {

            // sample the texture
            fixed4 col = tex2D(_MainTex, i.uv);
            return col;
        }
        ENDCG

view space计算

上面两种方式都是通过传入中心点坐标到shader进行计算，但是有时候并不能获得面片的中心点坐标，比如Unity中的SpriteRenderer，这时候的思路是：把中心点即（0，0，0，1）（Object space）转到View Space，然后顶点再做偏移。

---

            o.pos = mul(UNITY_MATRIX_P, 
              mul(UNITY_MATRIX_MV, float4(0.0, 0.0, 0.0, 1.0))
              + float4(i.vertex.x, i.vertex.y, 0.0, 0.0));

CPU计算

思路：面片的位置发生变化，或者摄像机发生变化的时候，重新计算一下面片的旋转，让它始终朝向摄像机

---

private void CalcBillboard()
{
    if(instance != null)
    {
        instance.transform.rotation = Camera.main.transform.rotation;
    }
}

link