ファイル操作 - stuncloud/UWSCR GitHub Wiki

// 読み取り
fid = fopen(path) // fopen(path, F_READ) と同等
print fget(fid, 1)
fclose(fid)

// 書き込み
fid = fopen(path, F_WRITE)
fput(fid, text)
fclose(fid) // 上書きされる

// 読み書き
fid = fopen(path, F_READ or F_WRITE)
print fget(fid, 1)
fput(fid, text)
fclose(fid) // 編集して保存

// エンコーディングを変更して保存
fid = fopen(path, F_WRITE1) // SJISでファイルを書き込み
fput(fid, text1)
fclose(fid)

fid = fopen(path, F_READ or F_WRITE16)
fput(fid, text2)
fclose(fid) // 編集してUTF-16で保存

// 追記
fopen(path, F_APPEND or F_WRITE16, text) // UTF-16で末尾に追記
fopen(path, F_APPEND) // エラー; F_APPEND指定時は第三引数が必須

// 自動ファイルクローズ
print fget(fopen(path, F_READ), F_ALLTEXT)
// ファイル識別子を変数に代入しなかった場合は読み書き関数実行後に自動でファイルが閉じられます

fid = fopen("test.csv", F_READ)

print fget(fid, 1) // foo,bar,baz
print fget(fid, 1, 1) // foo
// 前後のホワイトスペースはトリムされる
print fget(fid, 2, 1) // 「    foo   」にはならず「foo」が返る
// ダブルクォートで括られたカラム
print fget(fid, 3, 1, FALSE) // ダブルクォートありのカラム
print fget(fid, 3, 1, TRUE)  // "ダブルクォートありのカラム"
// 第4引数FALSEはUWSCにおける 2 の動作が標準になりました
print fget(fid, 3, 2, FALSE) // ダブルクォートの"エスケープ"
print fget(fid, 3, 2, TRUE)  // "ダブルクォートの""エスケープ"""
// 改行を含むカラムのサポート
// 第4引数がFALSEかつ改行を含む文字列がダブルクォートで括られている場合のみ
print fget(fid, 4, 1, FALSE) // 改行を
                             // 含む
print fget(fid, 4, 2, FALSE) // ここはまだ4行目

fclose(fid)

ini = 'test.ini'
print readini('foo', 'name', ini) // foo

// セクションを省略(またはEMPTY指定)するとセクション一覧を取得
print readini( , , ini) // [ section, foo, bar, baz ]
print readini( , 'name', ini) // ↑と同じ結果 (キーを渡しても無視される)

// セクションを指定してキーを省略(またはEMPTY指定)するとキー一覧を収録
print readini('section', , ini) // [ key1, key2, key3 ]

ini = fopen("hoge.ini", F_READ or F_WRITE)
// ファイルパスの代わりにfidを指定
print readini("hoge", "fuga", ini)        // 読む場合はF_READが必要
writeini("hoge", "fuga", "fugafuga", ini) // 書き込みにはF_READ or F_WRITEが必要
deleteini("hoge", "fuga", ini)            // 削除にもF_READ or F_WRITEが必要

fclose(ini) // iniファイルへの書き込みが反映される

id = getid( , "CabinetWClass") // Explorer

dropfile(id, "C:\test", "foo.txt") // C:\test\foo.txtをドロップ
dropfile(id, "C:\test", "foo.txt", "bar.txt", "baz.txt") // 10個まで指定可能

dropfile(id, "C:\test", ["foo.txt", "bar.txt", "baz.txt"]) // 配列指定も可能
bmps = getdir("C:\test", "*.bmp")
dropfile(id, "C:\test", bmps) // getdirで得たファイル名を渡す

// 第二第三引数が数値なら対象ウィンドウの相対座標として扱いその位置へドロップする
dropfile(id, 100, 100, "C:\test", "foo.txt")

files = [
    'foo.uws',
    'bar.uws',
    'baz.uws',
    'modules\qux.uws',
    'modules\quux.uws'
]

zip("test.zip", files)

unzip("test.zip", "out")

for file in getdir("out")
    print file
next
for dir in getdir('out', '\')
    for file in getdir("out\<#dir>")
        print "<#dir>/<#file>"
    next
next
// foo.uws
// bar.uws
// baz.uws
// modules\qux.uws
// modules\quux.uws

for item in zipitems("test.zip")
    print item
next
// foo.uws
// bar.uws
// baz.uws
// modules/qux.uws
// modules/quux.uws