スクリプト構文 - stuncloud/UWSCR GitHub Wiki

dim a = 1, b = 2, c, d[3], e[] = 1,2,3,4,5
public f = 1, g = 2
const h = 1, i = 2

dim hoge[] = 1, 2, 3 // 従来の配列定義
print hoge[0]

fuga = [1, 2, 3]     // 配列リテラル
print fuga[0]

print [4, 5, 6][0]   // 配列リテラルにインデックスを指定することも可能

print [1, 2, 3] + 4
// [1, 2, 3, 4]
dim arr = [5, 6, 7]
arr += 8
print arr
// [5, 6, 7, 8]

// 2次元
dim 配列名[要素数][要素数] = 値, 値, 値, 値 ...
// 3次元
dim 配列名[要素数][要素数][要素数] = 値, 値, 値, 値 ...

// 以下の書式も可能
dim 配列名[要素数, 要素数] = 値, 値, 値, 値 ...
dim 配列名[要素数, 要素数, 要素数] = 値, 値, 値, 値 ...

// 一番左の要素数のみ省略可能
dim 配列名[][要素数][要素数] = 値, 値, 値, 値 ...
dim 配列名[, 要素数, 要素数] = 値, 値, 値, 値 ...

// 呼び出しは次元数分だけ[]をつける

print 配列名[0][0][0] // 3次元配列の1つ目の要素

// 不足分はEMPTYで埋められる
dim sample1[2][1] = 0, 1, 2, 3
print sample1 // [[0, 1], [2, 3], [, ]]

// 超過分は捨てられる
dim sample2[1, 1] = 0, 1, 2, 3, 4, 5
print sample2 // [[0, 1], [2, 3]]

// 要素数省略
dim sample3[][1] = 1,2,3,4,5,6,7,8
print sample3 // [[1,2] ,[3,4], [5,6], [7,8]]

// 一番左以外は省略不可
dim bad_sample[][][1] // エラー

dim sample4[] = [1,2], [3,4], [5,6], [7,8]
sample5 = [[1,2] ,[3,4], [5,6], [7,8]]

hashtbl hoge
hoge["foo"] = 100
print hoge["foo"] // 100
hoge["FOO"] = 200
print hoge["foo"] // 200 大小文字区別がないため上書きされた
hoge["bar"] = 400
hoge["baz"] = 600

for i = 0 to length(hoge) - 1
    print hoge[i, HASH_KEY] // foo, bar, baz の順で表示される
    print hoge[i, HASH_VAL] // 200, 400, 600
next

print hoge["bar", HASH_EXISTS] // true
print hoge["qux", HASH_EXISTS] // false
hoge["bar", HASH_REMOVE] // 変数で受けなくてもOK
print hoge["bar", HASH_EXISTS] // false

hashtbl fuga = HASH_CASECARE
fuga["foo"] = 1
fuga["Foo"] = 2
fuga["FOO"] = 3
print fuga // {"foo": 1, "Foo": 2, "FOO": 3}

hashtbl piyo = HASH_SORT
piyo["b"] = ""
piyo["z"] = ""
piyo["a"] = ""
print piyo // {"A": , "B": , "Z": }

// 一括定義
hash foobar
    'foo' = 1 // キー = 値形式で記述
    bar   = 2 // キーは文字列でなくても良い
endhash
// 以下と同じ
// hashtbl foobar
// foobar['foo'] = 1
// foobar['bar'] = 2

// グローバル変数にする
hash public pub
endhash
// 以下と同じ
// public hashtbl pub

// オプション指定
hash with_option = HASH_CASECARE or HASH_SORT
endhash
// 以下と同じ
// hashtbl with_option = HASH_CASECARE or HASH_SORT

// 定義
enum 定数名
    メンバ名
    メンバ名 [ = 数値]
endenum

// 呼び出し
定数名.メンバ名

// 0から順に割り当てられる
enum E
    foo // 0
    bar // 1
    baz // 2
endenum

// 呼び出しは定数名.メンバ名
print E.foo // 0
print E.bar // 1
print E.baz // 2

// 数値を指定
enum E
    foo = 10 // 10
    bar = 20 // 20
endenum

// 一箇所指定するとそれ以降はその値から加算されていく
enum E
    foo = 10 // 10
    bar      // 11 (上の10 に +1される)
    baz      // 12
endenum

// 途中も可
enum E
    foo      // 0
    bar = 10 // 10
    baz      // 11
endenum
enum E
    foo = 100    // 100
    bar          // 101
    baz = 200    // 200
    qux          // 201
endenum

// 以下はNG

enum E
    foo
    foo // 同じ名前はダメ
endenum

// 前の数値より大きくないとダメ
enum E
    foo // 0
    bar // 1
    baz = 1 // 2以上じゃないとダメ
endenum
enum E
    foo = 50
    bar = 1 // 51以上じゃないとダメ
endenum

hoge(1,2,3) // 6
print fuga(1,2,3) // 6

procedure hoge(a, b, c)
    print a + b + c
fend
function fuga(a, b, c)
    result = a + b + c
fend

// エラーになる
procedure p()
    procedure q()
    fend
fend

a = 2
print a // 2
p(a)
print a // 6
q(a)
print a // 16

procedure p(ref r)
    r *= 3
fend

procedure q(var v)
    v += 10
fend

dim a[] = 1,2,3
p(a) // 3

// 配列ではない変数も受けられる
b = 12345
p(b) // 5

p("abc") // 変数じゃないのでダメ

procedure p(arr[])
    print length(arr)
fend

print f(2)    // 0
print f(2, 3) // 6

function f(n, m = 0)
    result = n * m
fend

// デフォルト値を省略した場合はEMPTYが入る
procedure p(arg = )
    print arg == EMPTY // True
fend

procedure p(a = 1, b = 2, c = 3) // ok 
fend
procedure q(a = 1, b, c = 3)     // エラー 
fend
procedure r(a, b = 2, c = 3)     // 前ならok 
fend

print f(1)         // 1
print f(1,2,3,4,5) // 5

function f(args v)
    result = length(v)
fend

procedure p(prms a, b)    // エラー
fend
procedure q(a, b, prms c) // ok
fend

function f(str: string)
    result = str
fend

print f("hoge") // OK
print f(123)    // 数値なのでエラー

// 列挙体名指定の場合
enum Hoge
    foo
    bar
    baz
endenum

function f2(n: Hoge)
    select n
        case Hoge.foo
            result = 'foo!'
        case Hoge.bar
            result = 'bar!'
        case Hoge.baz
            result = 'baz!'
    selend
fend

print f2(Hoge.foo) // OK
print f2("Hoge")   // 文字列はエラー
print f2(0)        // OK ※Hoge.fooに一致するため
print f2(100)      // Hogeに含まれない値なのでエラー

module sample
    dim d = 1
    public p = 2
    const c = 3

    function f1()
        // 各メンバーには以下のようにアクセス可能
        print d
        print this.d
        print sample.d

        print p
        print this.p
        print sample.p

        print c
        print this.c
        print sample.c

        print f2()
        print this.f2()
        print sample.f2()
    fend

    function f2()
        result = 4
    fend

    function f3()
        print this.f4()   // in   メンバ関数が呼ばれる
        print global.f4() // out  module外の関数が呼ばれる
        print f4()        // in   メンバ関数が呼ばれる
    fend

    function f4()
        result = "in"
    fend
endmodule

function f4()
    result = "out"
fend

h1 = hoge(3, 5)
print h1.Total() // 8

h2 = hoge(8, 10)
print h2.Total() // 18

print hoge(11, 22).Total() // 33

class hoge
    dim a = 1, b = 2
    procedure hoge(a, b)
        this.a = a
        this.b = b
    fend
    function Total()
        result = this.a + this.b
    fend
endclass

class Sample
    dim msg
    procedure Sample(msg)
        this.msg = msg
    fend
    procedure _Sample_()
        print msg
    fend
endclass

obj1 = Sample("すべての参照が失われた")
obj2 = obj1
obj3 = obj1

obj1 = 1
obj2 = 1
obj3 = 1 // すべての参照が失われた がprintされる

obj1 = Sample("NOTHINGが代入された")
obj2 = obj1
obj3 = obj1

obj1 = NOTHING // NOTHINGが代入された がprintされる
print obj1 // NOTHING
print obj2 // NOTHING
print obj3 // NOTHING

with Sample("withを抜けた")
endwith // withを抜けた がprintされる

procedure p()
    obj = Sample("関数スコープを抜けた")
fend

p() // 関数スコープを抜けた がprintされる

obj = @{
    "foo": "fooooo",
    "bar": {
        "baz": true
    },
    "qux": [
        {"quux": 1},
        {"quux": 2},
        {"quux": 3}
    ]
}@

arr = @[1, 2, 3]@

print obj.foo // fooooo
obj.foo = "FOOOOO"
print obj.foo // FOOOOO
print obj["foo"] // 配列の添字にしてもOK

print obj.bar.baz ? "baz is true!": "baz is fasle!" // baz is true!

obj.qux[1].quux = 5
print obj.qux[1].quux // 5

obj.qux[2] = "overwrite!"
print obj.qux[2] // overwrite!

obj.corge = 1 // エラー、追加はできない

// オブジェクトを作って代入ならOK
obj.foo = fromjson('{"hoge": 1, "fuga": 2}')
print obj.foo

変数 = function([引数, ...])
    [result = 戻り値]
fend
変数 = procedure([引数, ...])
fend

hoge = function(x, y)
    result = x + y
fend

print hoge(2, 3) // 5

// こういうのは無理
print (function(n)
    result = n * 2
fend)(5)

print x // エラー

proc = procedure()
    public x = 5
fend

print x // エラー

proc()

print x // 5

f = function(a, b[], var c, d = 0)
fend
p = procedure(args e)
fend

関数 = | 引数 [, 引数, …] => 式 [; 式; …] |

func = | a, b => a + b |
print func(1, 2) // 3

func = | a, b => a *= 2; b *= 3; a + b |
print func(1, 2) // 8

print | n, m => n * m |(7, 6) // 42
// 値だけ返す
print |=> 42|() // 42

// 関数の引数にする
function f(fn)
    result = fn("world!")
fend
print f(| s => "hello " + s |) // hello world!

print | args a => length(a) |(1,2,3,4,5,6) // 6

public global1 = "グローバル変数1"
dim local = "本文ローカル"

print global1 // ok
print global2 // ok
print local // ok
print proc_local // ng
print func() // ok

procedure proc()
    public global2 = "グローバル変数2"
    dim proc_local = "関数ローカル"
    print global1 // ok
    print global2 // ok
    print local // ng
    print proc_local // ok
    print func() // ok
fend

function func()
    result = "関数"
fend

str = "文字列"
str = '文字列'

str = "文字列" + "の" + "結合"
print str // 文字列の結合

print "hoge<#CR>fuga<#CR>piyo"
// hoge
// fuga
// piyo
print "hoge<#TAB>fuga<#TAB>piyo"
// hoge    fuga    piyo
print "<#DBL>hoge<#DBL>"
// "hoge"

dim a = 123
print "a is <#a>"
// a is 123
print "b is <#b>" // 変数が存在しない場合は展開されない
// b is <#b>
print "length of a is <#length(a)>" // 式はダメ、変数のみ展開される
// length of a is <#length(a)>

print 'a is <#a>' // シングルクォーテーション文字列は展開しない
// a is <#a>

print n := 1               // 1 (代入した値が返る)
print n                    // 1
print 1 + 2 + (n := 3) + 4 // 10 (代入した値が返り、その値で計算が行われる)
print n                    // 3

print NOTHING ? '真' : '偽' // 偽
print "" ? '真' : '偽' // 偽
print "空ではない文字列" ? '真' : '偽' // 真
print [1,2,3] ? '真' : '偽' // 真
print [] ? '真' : '偽' // 偽

print NaN == NaN // False
print n   == NaN // False (nは何かしらの値)
print NaN != NaN // True 
print NaN <  n   // False 
print NaN <= n   // False 
print NaN >  n   // False 
print NaN >= n   // False 

// bool値指定は省略可能で、省略時はtrueになります
// 例:
// OPTION EXPLICIT // explicit設定をtrueにする
// もともと設定がtrueになっているものをfalseに設定したい場合に値指定を使う
// OPTION SHORTCIRCUIT=FALSE // デフォルトtrueなのでfalseにする

// コメントアウトされているものは非対応か現時点では動作しないものです

OPTION EXPLICIT[=bool]             // ローカル変数初期化時にdim宣言が必須かどうか (初期値:false)
// OPTION SAMESTR[=bool]           // 文字列の比較等で大文字小文字を区別するかどうか (初期値:false)
// OPTION OPTPUBLIC[=bool]         // public変数の重複定義を禁止するかどうか (初期値:false)
OPTION OPTFINALLY[=bool]           // tryで強制終了時にfinally部を実行するかどうか (初期値:false)
// OPTION SPECIALCHAR[=bool]       // 互換性のため設定は可能ですが機能しません ※1
// OPTION SHORTCIRCUIT[=bool]      // 論理演算で短絡評価を行うかどうか (初期値:true)
// OPTION NOSTOPHOTKEY[=bool]      // 停止ホットキーを無効にするかどうか (初期値:false)
// OPTION TOPSTOPFORM[=bool]       // 停止ボタン実装の予定がありません
// OPTION FIXBALLOON[=bool]        // 吹き出しを仮想デスクトップにも表示するかどうか (初期値:false)
// OPTION DEFAULTFONT="name,n"     // ダイアログ等のフォント指定  (初期値:"MS Gothic,12")
// OPTION POSITION=x,y             // メインGUIの座標指定 (初期値:0, 0)
OPTION LOGPATH="path"              // ログ保存フォルダを指定 ※2 (初期値:スクリプトのあるフォルダ)
// OPTION LOGLINES=n               // ログファイルの最大行数を指定 (初期値:400)
OPTION LOGFILE=n                   // ログファイルの出力方法 ※3 (初期値:1)
// OPTION DLGTITLE="title"         // ダイアログのタイトル (初期値:"UWSCR - スクリプト名")

// ※1 '文字列'を使ってください
// ※2 存在するディレクトリを指定するとそこに`uwscr.log`を出力
//     それ以外はファイルパスとして扱われます
// ※3 現時点では細かい設定ができません
//     1: ログ出力なし
//     2: ログ出力あり
//     3: ログ出力あり
//     4: ログ出力あり
//     それ以外: ログ出力なし

def_dll 関数名(型, 型, ...): 戻り型: DLLパス
def_dll 関数名(型, 型, ...): DLLパス // 戻り値がvoidの場合省略できる

def_dll hoge({long, {long, long}}):hoge:dll
// ↑同じ↓
def_dll hoge({long, long, long}):hoge:dll

// Win32のA関数ではstringかpcharを使う
def_dll MessageBoxA(hwnd, string, string, uint):int:user32.dll
// Win32のW関数ではwstringかpwcharを使う
def_dll MessageBoxW(hwnd, wstring, wstring, uint):int:user32.dll

// 構造体定義は{}
def_dll SetWindowPlacement(hwnd, {uint, uint, uint, long, long, long, long, long, long, long, long}):bool:user32.dll

// 参照渡し
def_dll GetPrivateProfileStringA(string, string, string, var pchar, dword, string):dword:kernel32

// 構造体で実行後の値を受ける場合にvarは不要
def_dll GetCursorPos({long, long}):bool:user32.dll
// 構造体はそのサイズに合う配列でも代用可能
def_dll GetCursorPos(long[]):bool:user32.dll

// Win32のA関数ではstringかpcharを使う
def_dll MessageBoxA(hwnd, string, pchar, uint):int:user32.dll
// Win32のW関数ではwstringかpwcharを使う
def_dll MessageBoxW(hwnd, wstring, pwchar, uint):int:user32.dll

// 呼び出す際は単に文字列を渡すだけで良い
print MessageBoxA(0, 'メッセージ', 'タイトル', 0)
print MessageBoxW(0, 'メッセージ', 'タイトル', 0)

// 構造体定義は{}
def_dll SetWindowPlacement(hwnd, {uint, uint, uint, long, long, long, long, long, long, long, long}):bool:user32.dll
id = getid("メモ帳")
h = idtohnd(id)
// 構造体を渡すときは定義した型の数だけ値を並べる
SetWindowPlacement(h, 44, 0, 1, 0, 0, 0, 0, 200, 200, 600, 600)

// 参照渡し
def_dll GetPrivateProfileStringA(string, string, string, var pchar, dword, string):dword:kernel32
buffer = '                                                     '
// bufferがpcharなのでNULLを含んだ文字列が返ってくる
print GetPrivateProfileStringA(NULL, NULL, "default", buffer, length(buffer), "test.ini")
print buffer
def_dll GetPrivateProfileStringA(string, string, string, var string, dword, string):dword:kernel32
buffer = '                                                     '
// bufferをstringにすると最初のNULL以前の文字列のみ返ってくる
print GetPrivateProfileStringA(NULL, NULL, "default", buffer, length(buffer), "test.ini")
print buffer

// 構造体で値を受ける
// varは不要
def_dll GetCursorPos({long, long}):bool:user32.dll
dim x, y
print GetCursorPos(x, y)
print [x, y]

// 構造体はそのサイズに合う配列でも代用可能
// varは不要
def_dll GetCursorPos(long[]):bool:user32.dll
dim point = [0, 0] // long, long
print GetCursorPos(point)
print point

// 戻り値の型の制限
def_dll PathAddBackslashW(var string):string:ShlwApi.dll
path = "d:\hoge"
print PathAddBackslashW(path)
print path
// このような場合UWSCでは戻り値も文字列になりましたが、UWSCRでは安全のためこれをサポートしません
// この場合ポインタ(の数値)が返ります (その際警告文が標準出力されます)

struct 構造体名
    メンバ名: 型
    メンバ名: 構造体名
    ︙
endstruct

struct Point
    x: long
    y: long
endstruct

dim p = Point()
// xとyは0で初期化されるため以下のような初期化処理は記述不要
// p.x = 0
// p.y = 0

def_dll GetCursorPos(struct):bool:user32.dll
GetCursorPos(p)
print [p.x, p.y]


struct Hoge
    id: uint
    point: Point // 構造体名を指定
endstruct

h = Hoge()
print h.id // 0
// Pointも初期化される
print h.point.x // 0
print h.point.y // 0

struct SomeStruct
    foo: long
    bar: long
    baz: long
endstruct

// 
s = SomeStruct(pointer)
print s.foo

thread func()

// function宣言の前に async キーワードを付与
async function 関数名()
fend

async function MyFuncAsync(n)
    sleep(n)
    result = "<#n>秒待ちました"
fend

task = MyFuncAsync(5) // resultの値ではなくタスクを返す

// 以下と同じ結果になります
function MyFuncAsync(n)
    sleep(n)
    result = "<#n>秒待ちました"
fend

task = Task(MyFuncAsync, 5)

async function MyFuncAsync(n)
    sleep(n)
    result = "<#n>秒待ちました"
fend

// MyFuncAsync()の処理が終了するまで待つ
print await MyFuncAsync(5) // 5秒待ちました

with m
    print .p // m.p
    with .f() // m.f() のwithでネスト
        print .p // m2.p
    endwith
    print .p // m.p
endwith

module m
    public p = "m.p"
    function f()
        result = m2
    fend
endmodule

module m2
    public p = "m2.p"
endmodule

// 定数hogeが作られる
textblock hoge
foo
bar
baz
endtextblock

// 定数省略時はコメント扱い
// 値を呼び出すことができない
textblock
ここはコメントです
endtextblock

textblockex hoge
<#fuga>
endtextblock

fuga = 123
print hoge // 123
fuga = 456
print hoge // 456

call hoge.uws          // 実行するスクリプトからの相対パス
call hoge              // 拡張子のないファイルもOK、見つからない場合は.uwsを付けて開く
call fuga.uws(1, 2, 3) // 引数を渡すと PARAM_STR にはboolが入る

// urlから読み込み
call url[https://example.com/hoge.uws]        // url[ ] の中でurlを指定
call url[https://example.com/hoge.uws](1,2,3) // url[ ] の後に()をつけて引数を渡せる

call mylib.uwsl // 拡張子はuwslのみ (省略不可)

try
    try
    except
    endtry
finally
endtry

try
    print 1
    raise("エラー") // ここでエラー
    print 2 // 実行されない
except
    print TRY_ERRMSG // 実行される
endtry

try
    // エラーが発生しない場合
except
    print 1 // 実行されない
endtry

try
    print 1
    raise("エラー") // ここでエラー
    print 2 // 実行されない
finally
    print TRY_ERRMSG // 実行される
endtry

try
    // エラーが発生しない場合
finally
    print 1 // 実行される
endtry

try
    print 1
    raise("エラー") // ここでエラー
    print 2 // 実行されない
except
    print TRY_ERRMSG // 実行される
finally
    print TRY_ERRMSG // 実行される
endtry

try
    // エラーが発生しない場合
except
    print 1 // 実行されない
finally
    print 2 // 実行される
endtry

for i = 0 to length(items) - 1
    if items[i] == target then
        // 要素のいずれかがtargetと一致した場合break
        target_found()
        break
    endif
else
    // いずれの要素もtargetと一致しない場合はbreakしないのでこちらが実行される
    target_not_found()
endfor

// for-inにも対応
for item in items
    if item == target then
        target_found()
        break
    endif
else
    target_not_found()
endfor

// ループ内の処理が行われない場合でもelseが実行される
for i = 0 to -1
    print 1 // 実行されないため表示もされない
else
    print 2 // 2と表示される
endfor
for a in []
    print 3 // 実行されない
else
    print 4 // 4と表示される
endfor

exitexit [数値]

// 通常はCOMエラーで動作停止する
obj = createoleobj("Some.ComObject")
obj.FireError() // COMエラー！

// COMエラーを抑制するパターン
obj = createoleobj("Some.ComObject")
// COMエラー抑制開始
COM_ERR_IGN

print COM_ERR_FLG // False
obj.FireError() // エラーになるがスクリプトは停止しない
print COM_ERR_FLG // Trueになる

// COMエラー抑制終了
COM_ERR_RET

print COM_ERR_FLG // True; COM_ERR_RETでは初期化されない

obj.FireError() // 抑制していないのでCOMエラー

// 従来
hoge = [ _
    "foo", _
    "bar", _
    "baz"  _
]
// 0.5.0以降
hoge = [
    "foo",
    "bar",
    "baz"
]

// 配列リテラル
print [     // [ の後の改行
    "foo",  // カンマの後の改行
    "bar"   // 式の後の改行
    ,"baz"  // カンマを式の前に書いてもいい
]           // ] 前の改行

// 関数呼び出し
print func( // ( の後の改行
    foo,    // カンマの後の改行
    ,       // 引数省略
    bar     // 式の後の改行
    ,baz    // カンマを式の前に書いてもいい
)           // ) 前の改行

// 関数定義
function hoge(
    a,
    ref b,
    c: string,
    d = 1
)
    b = do_something_with(a)
    do_something_with(c, d)
fend

// def_dll
def_dll MessageBoxA(
    hwnd,
    string,
    string,
    uint
):int:user32

// 以下は対象外

// dim配列宣言で改行するとエラーになる
dim fuga[] = 1,
             2,
             3
// 必ず一行で書く
dim hoge[] = 1,2,3

// select文case句の複数条件で改行するとエラー
select fuga
    case 1,
         2,
         3
        print "ng"
selend
// 必ず一行で書く
select hoge
    case 1,2,3
        print "ok"
selend