// queryDsl을 통해 자동을 생성되는 QType의 저장 경로
def queryDslOutput = hasProperty("querydslGeneratedDir") ? querydslGeneratedDir : "src/main/generated"
def queryDslOutputDir = file(queryDslOutput)
 
println displayName + " QueryDsl Generated Q-Type output dir : " + queryDslOutput
 
// queryDsl을 통해 자동을 생성되는 QType의 저장 경로를 소스디렉토리로 포함시킨다.
sourceSets {
    main {
        java {
            srcDirs += queryDslOutputDir
        }
    }
}
 
dependencies {
    compile 'com.querydsl:querydsl-apt'
}
 
// QType 생성 task
task generateQueryDSL(type: JavaCompile, group: 'build') {
    doFirst {
        if (!queryDslOutputDir.exists()) {
            logger.info("Creating `$queryDslOutputDir` directory")
 
            if (!queryDslOutputDir.mkdirs()) {
                throw new InvalidUserDataException("Unable to create `$queryDslOutputDir` directory")
            }
        }
    }
 
    source = sourceSets.main.java
    classpath = configurations.compile
    options.compilerArgs = [
        "-proc:only",
        "-processor",
        "com.querydsl.apt.jpa.JPAAnnotationProcessor"
    ]
    destinationDir = queryDslOutputDir
}
 
// 클린 시 queryDsl을 통해 자동을 생성되는 QType의 저장 경로도 삭제한다.
clean {
    //noinspection GroovyAssignabilityCheck
    delete queryDslOutputDir
}

apply from: "$rootProject.projectDir/queryDsl.gradle"
// ...
compileJava.dependsOn(generateQueryDSL)