Cython应用 - mouse3150/mouse3150.github.io GitHub Wiki

Cython是一个快速生成Python扩展模块的工具，从语法层面上来讲是Python语法和C语言语法的混血，当Python性能遇到瓶颈时，Cython直接将C的原生速度植入Python程序，这样使Python程序无需使用C重写，能快速整合原有的Python程序，这样使得开发效率和执行效率都有很大的提高，而这些中间的部分，都是Cython帮我们做了，接下来简单说一下Cython的安装和使用方法。

Cython官网地址是：http://cython.org/ 这里有cython的安装和开发文档，关于Cython的下载可以在pypi上直接下载安装包：https://pypi.python.org/pypi/Cython/ 由于是在Linux下安装使用，这里下载的是Cython-0.25.2.tar.gz，上传至linux执行如下步骤安装：

tar -xvzf Cython-0.25.2.tar.gz
cd Cython-0.25.2
python setup.py install

Cython使用

这样Cython模块就安装成功了 　　然后我们首先看一下cython的基本使用，首先 mkdir hello_pack && cd hello_pack 建立一个目录并且进入，然后编写一个hello.pyx的脚本，代码如下：

# coding=utf-8
def print_hello(name):
    print "Hello %s!" % name

然后编写一个setup.py，代码如下：

from distutils.core import setup
from distutils.extension import Extension
from Cython.Distutils import build_ext
ext_modules = [Extension("hello",["hello.pyx"])]
setup(
    name = "Hello pyx",
    cmdclass = {'build_ext': build_ext},
    ext_modules = ext_modules
)

这里导入了Cython的模块，其中setup name指定模块的名称，然后执行编译命令：

python setup.py build_ext --inplace

编译完之后，看到当前目录下会生成两个文件，一个是hello.c一个是hello.so，hello.c就是转换而成的c代码，而hello.so就是我们需要的python经过Cython编译之后的模块，我们为了当前目录可被调用，建立__init__.py内容如下：

# coding=utf-8
from hello import *

然后执行 cd .. 回到上层目录，建立一个hello.py，代码如下：

#!/usr/bin/python
# coding=utf-8
from hello_pack import hello
hello.print_hello("cython")

执行hello.py输出打印字符串

其实setup.py编译脚本也可以写成如下这样：

from distutils.core import setup
from Cython.Build import cythonize
setup(
    name='Hello pyx',
    ext_modules=cythonize('hello.pyx')
)

这种写法更通用，编译的时候直接使用 python setup.py build 就可以了，注意不是install，执行install后会把模块复制到python系统目录下了；执行完之后，会看到当前目录有一个build目录，然后进去会发现有如下两个目录。

第二个temp是编译过程中汇编生成的.o文件，第一个lib开头的目录中存放的就是hello.so文件，直接把这个文件拷贝出来就可以使用了，另外为了方便，运行脚本直接和so文件放在一个目录下就可以，直接使用import hello即可导入，也不用建立__init__.py了。

Cython和Python程序性能

　　首先我们编写一个compute.py，封装了两个计算的方法，代码如下：

# coding=utf-8
import math
def spherical_distance(lon1, lat1, lon2, lat2):
    radius = 3956
    x = math.pi/180.0
    a = (90.0 - lat1)*x
    b = (90.0 - lat2)*x
    theta = (lon2 - lon1)*x
    distance = math.acos(math.cos(a)*math.cos(b)) + (math.sin(a) * math.sin(b) * math.cos(theta))
    return radius * distance

def f_compute(a, x, N):
    s = 0
    dx = (x - a)/N
    for i in range(N):
        s += ((a + i * dx) ** 2 - (a + i * dx))
    return s * dx

代码就是分别执行100000次数字计算和距离计算，并打印之间，执行结果如下：

runing1 time: 0.330000
runing2 time: 1.340000

可以看到数字计算耗时0.33s，距离计算耗时1.34s，然后我们尝试直接用Cython模块进行编译，首先复制出来一份 cp compute.py compute1.pyx 然后编写setup1.py

from distutils.core import setup
from Cython.Build import cythonize
setup(
    name='compute_module',
    ext_modules=cythonize('compute1.pyx'),
)

写完之后直接执行 python setup1.py build 编译，编译完之后导入compute1.so这个模块，现在只需要修改头部import compute为import compute1 as compute这样能保证下面调用代码不变，然后执行，结果如下：

runing1 time: 0.250000
runing2 time: 0.940000

现在会发现时间比刚才快了一点，说明性能有所提升，然后继续进行优化，这次全部变量都使用静态类型，即变量类型提前定义，compute2.pyx代码如下：

# coding=utf-8
import math
cpdef float spherical_distance(float lon1, float lat1, float lon2, float lat2):
    cdef float radius = 3956
    cdef float pi = 3.14159265
    cdef float x = pi/180.0
    cdef float a,b,theta,distance
    a = (90.0 - lat1)*x
    b = (90.0 - lat2)*x
    theta = (lon2 - lon1)*x
    distance = math.acos(math.cos(a)*math.cos(b)) + (math.sin(a) * math.sin(b) * math.cos(theta))
    return radius * distance

def f_compute(double a, double x, int N):
    cdef int i
    cdef double s = 0
    cdef double dx = (x - a)/N
    for i in range(N):
        s += ((a + i * dx) ** 2 - (a + i * dx))
    return s * dx

现在可以看到类型全部做了定义，在cython里面，类型定义使用cdef float这种方式进行；对于方法来说，如果模块内部相互调用那么同样使用cdef double这种的方式来定义，如果这个方法要在我们外部执行脚本中调用，那么要么是python原生方法不做任何修改，要么写成cpdef float这种类型的形式，方法定义类型可以提高效率，但是提高不大，但是变量静态类型可以极大的提高效率，原因是参与计算的主要是变量；假如一个函数被频繁调用，那么有必要使用cdef或者cpdef来定义；现在同样方法编译compute2模块，然后在test.py中调用，执行结果如下：

runing1 time: 0.000000s
runing2 time: 0.810000s

现在发现纯数字计算的时间几乎变成了0秒！而第二个用了0.81s，比刚才快了，但是似乎并不是很快，原因仔细想想会发现，这里面调用了很多三角函数，使用的还是python内置的math模块，这里可以用C语言的math.h来代替，所以再写一个compute3.pyx如下：

# coding=utf-8
#import math
cdef extern from "math.h":
    float cosf(float theta)
    float sinf(float theta)
    float acosf(float theta)

def spherical_distance(float lon1, float lat1, float lon2, float lat2):
    cdef float radius = 3956
    cdef float pi = 3.14159265
    cdef float x = pi/180.0
    cdef float a,b,theta,distance
    a = (90.0 - lat1)*x
    b = (90.0 - lat2)*x
    theta = (lon2 - lon1)*x
    distance = acosf(cosf(a)*cosf(b)) + (sinf(a) * sinf(b) * cosf(theta))
    return radius * distance

def f_compute(double a, double x, int N):
    cdef int i
    cdef double s = 0
    cdef double dx = (x - a)/N
    for i in range(N):
        s += ((a + i * dx) ** 2 - (a + i * dx))
    return s * dx

这次我们屏蔽了自身的math模块，然后调用了C的头文件math.h，并引入了cosf,sinf,acosf，实际上这三个函数返回的都是float类型，和我们定义的一致，如果我们想使用double类型，那么应该直接使用cos,sin,acos函数，并且我们可以对这些函数再包装，这样cpdef就派上用场了，比如下面：

cdef extern from "math.h":
    double cos(double)
    double sin(double)

cpdef double tangent(double x):
    return sin(x)/cos(x)

比如这里定义了一个测试的tangent正切函数，就是上面这样写；同样我们现在编译compute3.pyx并测试，结果如下：

runing1 time: 0.000000s
runing2 time: 0.030000s

现在第一个仍然是接近于0s完成，而第二个三角函数换成C的之后，性能有的非常大的提升，可以说几乎接近于原生C语言的效率了，这样看来从Python到Cython性能得到了很大的优化，但是代码量确差别没有用C重写那么大

　　根据上面的案例，我们知道在数字，浮点数等计算中Cython可以极大的提高性能，而这方面多线程几乎不能提高任何性能，有时候反而会降低；但是对于io密集型的场合，用Cython基本上也没有性能上太大的提升，而多线程的将拥有更加出色的性能，所以Cython应该专注与计算方面的优化；总结一下也就是对于IO密集型应用，优化可以考虑使用多线程或者多进程方式，对于计算密集型的场合，遇到瓶颈时可以考虑使用Cython或者封装C相关的模块

　　最后，虽然Cython非常好用，但也不能疯狂的使用，推荐一句名言：我们应该忘记小的效率,过早的优化是一切罪恶的根源,有 97% 的案例如此。简单来说就是选择恰当的时机进行优化