Algoritmo ValidarParentesis - jsyh1/practica_aplicada GitHub Wiki

Algoritmo ValidarParentesis

Definir expresion, caracter Como Cadena
Definir abiertos, cerrados, i Como Entero
Definir valido Como Logico

Escribir "Ingrese una expresion con parentesis:"
Leer expresion

abiertos <- 0
cerrados <- 0
valido <- Verdadero

Para i <- 1 Hasta Longitud(expresion) Hacer
	
	caracter <- Subcadena(expresion, i, i)
	
	Si caracter = "(" Entonces
		
		abiertos <- abiertos + 1
		
	FinSi
	
	Si caracter = ")" Entonces
		
		cerrados <- cerrados + 1
		
		Si cerrados > abiertos Entonces
			
			Escribir "Error: se encontro un parentesis de cierre sin un parentesis de apertura correspondiente."
			valido <- Falso
			
		FinSi
		
	FinSi
	
FinPara

Si valido Entonces
	
	Si abiertos > cerrados Entonces
		
		Escribir "Error: existen ", abiertos - cerrados, " parentesis de apertura sin cerrar."
		valido <- Falso
		
	FinSi
	
FinSi

Si valido Entonces
	
	Escribir "Los parentesis son validos y estan correctamente balanceados."
	
FinSi

FinAlgoritmo