Methode Outbound Delivery by Docno - jpnqs/ABAP_Wiki GitHub Wiki

GET_ODO_BY_DOCNO

Signatur

Parameter	Typing	Description
IT_DOCNO	TYPE /SCWM/DLV_DOCNO_ITEMNO_TAB	Document Number
IV_LGNUM	TYPE /SCWM/LGNUM	Warehouse Number/Warehouse Complex
ET_ODO_HEADER	TYPE /SCWM/DLV_HEADER_OUT_PRD_TAB	Delivery Header (PRD) for Read Operations
ET_ODO_ITEMS	TYPE /SCWM/DLV_ITEM_OUT_PRD_TAB	Delivery Item (PRD) for Read Operations
CX_STATIC_CHECK	Exceptions with Static and Dynamic Check of RAISING Clause

Code

    DATA: lo_dlv_mgr   TYPE REF TO /scwm/cl_dlv_management_prd,
          ls_read_opts TYPE /scwm/dlv_query_contr_str,
          ls_inc_data  TYPE /scwm/dlv_query_incl_str_prd,
          lt_selection TYPE /scwm/dlv_selection_tab.

    lt_selection = VALUE #(
      FOR ls_docno IN it_docno (
        fieldname = c_field_docno
        sign      = wmegc_sign_inclusive
        option    = wmegc_option_eq
        low       = |{ ls_docno-docno ALPHA = IN }|
      )
    ).

    ls_read_opts = VALUE #(
      item_part_select         = abap_true
      docflow_succ_1level_only = abap_true
      data_retrival_only       = abap_true
      mix_in_object_instances  = abap_true
    ).

    ls_inc_data = VALUE #(
      head_partyloc    = abap_true
      head_date        = abap_true
      head_addmeas     = abap_true
      head_status      = abap_true
      head_refdoc      = abap_true
      head_transport   = abap_true
      head_status_dyn  = abap_true
      item_partyloc    = abap_true
      item_date        = abap_true
      item_addmeas     = abap_true
      item_status      = abap_true
      item_refdoc      = abap_true
      item_splittab    = abap_true
      item_hierarchy   = abap_true
      item_serialn     = abap_true
      item_od          = abap_true
      item_batchid     = abap_true
      item_chval       = abap_true
      item_product_ext = abap_true
      item_prcode      = abap_true
      item_account     = abap_true
      item_docflow     = abap_true
    ).

    lo_dlv_mgr = NEW #( ).

    lo_dlv_mgr->query( EXPORTING iv_whno         = iv_lgnum
                                 it_selection    = lt_selection
                                 iv_doccat       = wmegc_doccat_pdo
                                 is_read_options = ls_read_opts
                                 is_include_data = ls_inc_data
                       IMPORTING et_headers      = et_odo_header
                                 et_items        = et_odo_items ).