World Creator - ShaneBeee/SkBee GitHub Wiki

SkBee allows you to create simple worlds, similar to that of a world management plugin such as MultiVerse.

CREATING A WORLD CREATOR

To get started, we will need to create a new world creator.

The syntaxes are quite simple

[a] [new] world creator (with name|named) %string%
[a] [new] world creator (with name|named) %string% to (copy|clone) %world%

We have an option to create a new creator (new world) or to copy (copy a worlds seed and settings) or clone (copy/paste an already generated world)
Let's see it in action

set {_w} to a world creator named "my-world"

EASY PEASY!!!

CREATOR OPTIONS

We can set some simple options for our new world

[the] (environment|world type|world seed|gen[erator] settings|generator|should gen[erate] structures|[is] hardcore|keep spawn loaded|load on start) [option] of %worldcreator%

environment = this is the type of environment our world will be, the options are normal (overworld), nether and the end (defaults to normal).
world type = this is the type of world we are creating, the options are: normal, amplified, flat, large biomes, buffet, customized, legacy version (these may differ depending on which server version you are running) (defaults to normal)
seed = this is a number, for the seed of the world
generator settings = this is the settings for the generator, generally used for FLAT worlds (see Spigot API for more info)
generator = This is a world generator you may use, specifically from another plugin
should generate structures = if structures should generate
hardcore = if the world will be a hardcore world
keep spawn loaded = if the world should keep its spawn in memory when loaded
load on start = if the world should automatically load when the server loads (do not enable this if you are using a chunk generator).
example:

set {_w} to new world creator named "my-world"
set seed option of {_w} to 238654
set environment option of {_w} to nether

LOAD WORLD FROM CREATOR

Once we have finished, we can load our newly created world.
Syntax:

load world from [[world] creator] %worldcreator%

Example:

set {_w} to new world creator named "my-world"
set seed option of {_w} to 238654
set environment option of {_w} to nether
load world from creator {_w}

LOAD WORLD

You can also load a world that was previously created, but not currently loaded.
This can be useful if you are importing a world that was previously created elsewhere.

Syntax:

load world %string%

Example:

load world "my-world"

NOTE:

Worlds created then loaded by SkBee will be added to the SkBee world config (found in plugins/SkBee/worlds.yml).
Upon server load, these worlds will NOT load automatically.
You can enable this feature in the SkBee config if you wish to automatically load your worlds.
You can also set each world individually to load automatically.

UNLOAD WORLD

You can unload a world.
It is highly recommended to teleport all players out of this world before unloading it. If you don't, all players will be teleported to the spawn of the main world. If you are unloading your main world, you should probably TP them elsewhere. IF not, the world will not unload. You can also choose whether or not you want to save the world before unloading. Default will save.

Syntax:

unload [world] %world% [and (0¦save|1¦(do not|don't) save)]

Example:

unload world "my-world"

DELETE WORLD FILE

If you are done with a world, you can delete the world file. You will ONLY be able to delete custom worlds, NOT default Minecraft worlds or worlds created by other plugins. This is a safety precaution. If you need to delete those worlds, stop your server and do so. Before deleting a world it is good practice to unload it first. If you forget, SkBee will try to unload it for you. If it does not unload, it will not delete. Another safety precaution.

Syntax:

delete world file for [world] %string%

Example:

delete world file for "my-world"

VOID WORLD

I have been asked this a couple of times on how to make a "VOID WORLD", so after some research and a lot of trial and error, I present to you, code to make a void world:

set {_w} to world creator named "world_void"
set world type option of {_w} to flat
set generator settings option of {_w} to "{""biome"": ""minecraft:plains"",""layers"": []}}"
set should generate structures option of {_w} to false
load world from {_w}

Enjoy!!!

Ok, I think that about sums this all up. Happy World Creating!!!