Evaluation of Cypher and SPARQL for KnetMiner - Rothamsted/knetminer GitHub Wiki

//Q1: Path length = 1; All direct neighbours of target gene (ignore direction)
MATCH p = (g:Gene)--() 
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q2: Path length = 2; direction: Gene-->A-->B
MATCH p = (g:Gene)-->()-[:ortho|:h_s_s|:xref|:has_domain|:associated_with|:pub_in|:has_function|:participates_in|:cat_c|:cooc_wi|:is_a]->()
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q3: Path length = 2; special case: [cooc_wi] can be in both directions
MATCH p = (g:Gene)-->()-[:cooc_wi]-(:TO)
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q4: Path length = 3; direction: Gene-->A-->B-->C
MATCH p = (g:Gene)-->()-[:ortho|:h_s_s|:xref|:has_domain]->()-[:pub_in|:has_function|:participates_in|:equ|:xref|:cat_c]->()
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q5: Path length = 4; Gene-->A--B<-[enc]-C-->D
MATCH p = (g:Gene)-->()-[:ortho]->()<-[:enc]-()-[:pub_in|:has_function|:participates_in|:has_variation|:has_observ_pheno|:differentially_expressed]->()
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q6: Path length = 4; special case: Gene-->A--B<-[enc]-C-[cooc_wi]-D 
MATCH p = (g:Gene)-->()-[:ortho]->()<-[:enc]-()-[:cooc_wi]-(:TO)
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q7: Path length = 4; special case: Gene-->A--B<-[enc]-C-[physical|genetic]-D; merging Q6 and Q7 is twice as slow 
MATCH p = (g:Gene)-->()-[:ortho]->()<-[:enc]-()-[:physical|:genetic]-()
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q8: Path length = 5; Gene-->A--B<-[enc]-C-->SNP-->Trait
MATCH p = (g:Gene)-->()-[:ortho]->()<-[:enc]-()-[:has_variation]->()-[:associated_with]->(:Trait)
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q9: Path length = 5; Gene-->A--B<-[enc]-C--D-->E
MATCH p = (g:Gene)-->()-[:ortho]->()<-[:enc]-()-[:physical|:genetic]-()-[:has_function|:participates_in|:has_observ_pheno]->()
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q10: Path length = 5; Gene-->Protein-->Protein<-[enc]-Gene-->Gene--TO
MATCH p = (g:Gene {name:'RIN4'})-[:enc]->(:Protein)-[:ortho]->(:Protein)<-[:enc]-(:Gene)-[:physical|:genetic]-(:Gene)-[:cooc_wi]-(:TO)
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q11: Path length = 6; Gene-->A-->B<-[enc]-Gene--Gene-->SNP-->Trait
MATCH p = (g:Gene)-->()-[:ortho]->()<-[:enc]-()-[:physical|:genetic]-()-[:has_variation]->()-[:associated_with]->(:Trait)
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p
UNION
//Q12: Path length = 6; Gene-->A-->B-[xref]-Protein-->Enzyme--Reaction-->Pathway
MATCH p = (g:Gene)-->()-[:ortho]->()-[:xref]-()-[:is_a]-()-[:ca_by]-()-[:part_of]->(:Path)
WHERE 'RIN4' IN ( g.prefName OR 'RIN4' + g.altName )
RETURN p

PREFIX  odx:  <http://ondex.sourceforge.net/ondex-core#>
PREFIX  odxc: <http://www.ondex.org/ex/concept/>
PREFIX  odxcc: <http://www.ondex.org/ex/conceptClass/>
PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX  odxr: <http://www.ondex.org/ex/relation/>
PREFIX  odxrt: <http://www.ondex.org/ex/relationType/>

SELECT DISTINCT ?g ?a ?b ?c ?d ?e
{
  ?g a odxcc:Gene;
     odx:conceptName 'RIN4'.

  # Q1
  ?g ?pa ?a.
  ?a odx:conceptName ?aname.

  # Q3
  OPTIONAL {
    ?a odxrt:cooc_wi ?b.
    ?b a odxcc:TO.
  }

  OPTIONAL {
    # Q2
    { ?a odxrt:ortho|odxrt:h_s_s|odxrt:xref|odxrt:has_domain|odxrt:associated_with|odxrt:pub_in|odxrt:has_function|odxrt:participates_in|odxrt:cat_c|odxrt:cooc_wi|odxrt:is_a ?b }

    # Q12
    UNION {
      ?a odxrt:ortho ?b.
      ?b (odxrt:xref|^odxrt:xref)/(odxrt:is_a|^odxrt:is_a)/(odxrt:ca_by|^odxrt:ca_by)/(odxrt:part_by|^odxrt:part_of) ?c.
      ?c a odxcc:Path
    }

    UNION {
      ?a odxrt:ortho ?b.
      ?c odxrt:enc ?b.

      # Q5
      { ?c odxrt:pub_in|odxrt:has_function|odxrt:participates_in|odxrt:has_variation|odxrt:has_observ_pheno|odxrt:differentially_expressed ?d. }

      # Q6
      UNION { ?c odxrt:cooc_wi ?to. ?d a odxcc:TO }

      # Q7
      UNION { ?c odxrt:physical|^odxrt:physical|odxrt:genetic|^odxrt:genetic ?d }

      # Q8
      UNION { ?c odxrt:has_variation/odxrt:associated_with ?e. ?e a odxcc:Trait }

      UNION {
        ?c (odxrt:physical|^odxrt:physical|odxrt:genetic|^odxrt:genetic) ?d

        # Q9
        { ?d (odxrt:has_function|odxrt:participates_in|odxrt:has_observ_pheno) ?e }

        # Q10
        UNION {
          ?d odxrt:cooc_wi ?e.
          ?c a odxcc:Gene.
          ?d a odxcc:Gene.
          ?e a odxcc:TO.
        }

        # Q11
        UNION { ?d odxrt:has_variation ?e }
      } # level following c
    } # level following b 
  } # level following ?a 
}
LIMIT 1000