#include "RTClib.h" //библиотека часов реального времени
#include <LiquidCrystal_I2C.h>  //библиотека дисплея LCD1602
#include <Adafruit_BMP280.h>  //библиотека датчика BMP280
#include <Adafruit_GFX.h> //библиотека вычислений GFX
#include "TM1637.h" //библиотека сегментного индикатора
#include "DHT.h"  //библиотека датчика DH11
#include <SPI.h>  //библиотека шины SPI для работы с SD
#include <SD.h> //библиотека работы с SD картой
#include <Max72xxPanel.h> //библиотека матрицы Бегущая строка

//#define useSD
#define useDH11
//#define useBMP280
#define useLCD1602
//#define useTICKER   //бегущая строка
//#define useSEGMSCR  //сегментный индикатор

#define addrLCD       0x38  //адрес дисплея LCD1602
#define dht11PIN      8    //пин датчика DH11
#define sdPIN         9       //пин SD
#define csMtrxPIN     5       //пин Matrix CS
#define countTicker   4       //количество матриц Бегущая строка

String paramStr;
float temperature;
float pressure;
float altitude;
float humidity;

#ifdef useDH11
  DHT dht11(dht11PIN, DHT11);
#endif

#ifdef useBMP280
  #define BMP_SCK  13
  #define BMP_MISO 12
  #define BMP_MOSI 11
  #define BMP_CS   8
  Adafruit_BMP280 bmp280(BMP_CS, BMP_MOSI, BMP_MISO,  BMP_SCK);
#endif

#ifdef useLCD1602
  LiquidCrystal_I2C lcd(addrLCD,16,2);
#endif

#ifdef useSEGMSCR
  TM1637 tm1637(6,7);
#endif

#ifdef useTICKER
  Max72xxPanel matrix = Max72xxPanel(csMtrxPIN, countTicker, 1);
#endif

RTC_DS1307 RTC;

void setup(){
  Serial.begin(115200);
  
  Wire.begin(); //инициализируем шину I2C

  #ifdef useLCD1602 //инициализируем LCD1602
    lcd.init();
    lcd.clear();
    lcd.backlight();
  #endif

  #ifdef useSEGMSCR
    tm1637.init();
    tm1637.set(BRIGHT_TYPICAL);
  #endif

  #ifdef useBMP280   //инициализируем BMP280
    if(!bmp280.begin()){
      Serial.println("BMP280 Error");
    }
  #endif
  
  #ifdef useDH11   //инициализируем DH11
    dht11.begin();
  #endif

  #ifdef useSD
  if(!SD.begin(sdPIN)){
    Serial.println("SD Error");
    Serial.println("Break start");while(1){}
  }
  #endif

  RTC.begin();
  //RTC.adjust(DateTime(__DATE__, __TIME__)); //установить время компьютера
  
  if(!RTC.isrunning()){
    Serial.println("RTC Error");
    Serial.println("Break start");while(1){}
  }
  Serial.println("Std");
}
 
void loop(){
  DateTime now = RTC.now();
  
  #ifdef useDH11
    temperature = dht11.readTemperature();
    humidity = dht11.readHumidity();
    #ifdef useLCD1602
      lcd.setCursor(5,0);
      if(now.hour() < 10){lcd.print("0");}lcd.print(now.hour());lcd.print(":");
      if(now.minute() < 10){lcd.print("0");}lcd.print(now.minute());
      lcd.setCursor(0,1);lcd.print("T=");lcd.print(temperature) + "C";
      lcd.setCursor(9,1);lcd.print("H=");lcd.print(humidity);
    #endif
    #ifdef useTICKER
      String mxStr = "";
      if(now.hour() < 10){mxStr += "0";}mxStr += String(now.hour()) + ":";
      if(now.minute() < 10){mxStr += "0";}mxStr += String(now.minute());
      mxStr += " t=" + String(int(temperature)) + "C  H=" + String(int(humidity)) + "%";
      matrixPrint(mxStr);
    #endif
    #ifdef useSEGMSCR
      String dTemp = String((int)temperature);
      tm1637.display(0, dTemp[0]-48);
      tm1637.display(1, dTemp[1]-48);
      tm1637.display(3, 12);
    #endif
    
  #endif

  #ifdef useBMP280
    temperature = bmp280.readTemperature();
    pressure = bmp280.readPressure()*0.00750063755419211;
    altitude = bmp280.readAltitude(1013.25);
    #ifdef useLCD1602
      lcd.setCursor(5,0);
      if(now.hour() < 10){lcd.print("0");}lcd.print(now.hour());lcd.print(":");
      if(now.minute() < 10){lcd.print("0");}lcd.print(now.minute());
      lcd.setCursor(0,1);lcd.print("T=");lcd.print(temperature) + "C";
      lcd.setCursor(9,1);lcd.print("P=");lcd.print(pressure);
    #endif
    #ifdef useTICKER
      String mxStr = "";
      if(now.hour() < 10){mxStr += "0";}mxStr += String(now.hour()) + ":";
      if(now.minute() < 10){mxStr += "0";}mxStr += String(now.minute());
      mxStr += " t=" + String(int(temperature)) + "C P=" + String(int(pressure)) + " A=" + String(int(altitude));
      matrixPrint(mxStr);
    #endif
    #ifdef useSEGMSCR
      String dTemp = String((int)temperature);
      tm1637.display(0, dTemp[0]-48);
      tm1637.display(1, dTemp[1]-48);
      tm1637.display(3, 12);
    #endif
  #endif

  paramStr = "";
  paramStr += String(now.hour());paramStr += ":";
  paramStr += String(now.minute());paramStr += ":";
  paramStr += String(now.second());
  paramStr += " T:";paramStr += String(temperature);
  paramStr += " P:";paramStr += String(pressure);
  paramStr += " A:";paramStr += String(altitude);
  paramStr += " H:";paramStr += String(humidity);
  
  #ifdef useSD
  File dataFile = SD.open("file.txt", FILE_WRITE);
  dataFile.println(paramStr);
  dataFile.close();
  #endif

  Serial.println(paramStr);

}

void matrixPrint(String tape){
  #ifdef useTICKER
  int spacer = 1;
  int width = 5 + spacer;
  for ( int i = 0 ; i < width * tape.length() + matrix.width() - 1 - spacer; i++ ) {

    matrix.fillScreen(LOW);

    int letter = i / width;
    int x = (matrix.width() - 1) - i % width;
    int y = (matrix.height() - 8) / 2; // center the text vertically

    while ( x + width - spacer >= 0 && letter >= 0 ) {
      if ( letter < tape.length() ) {
        matrix.drawChar(x, y, tape[letter], HIGH, LOW, 1);
      }

      letter--;
      x -= width;
    }

    matrix.write(); // Send bitmap to display

    delay(30);
  }
  #endif
}