Tiny SSDT example 1: ASUS P8P67 M PRO - RevoGirl/RevoBoot GitHub Wiki

External (\_SB.PCI0, DeviceObj)
External (\_SB.PCI0.P0P1, DeviceObj)
External (\_SB.PCI0.PEX4, DeviceObj)
External (\_SB.PCI0.PEX5, DeviceObj)

Scope (\_SB.PCI0)
{
    Name (PW94, Package (0x02) { 0x09, 0x04 })

    Device (MCHC) // Required for PM.
    {
        Name (_ADR, Zero)
    }

    Device (HDEF) // Adding name for AppleHDA.kext
    {
        Name (_ADR, 0x001B0000)
        Alias (PW94, _PRW)
    }
}

Scope (\_SB.PCI0.P0P1)
{
    Device (GFX0) // Adding name for the graphics card.
    {
        Name (_SUN, One) // Added for Profile Manager.
        Name (_ADR, Zero)
    }

    Device (HDAU) // Adding name for HDMI interface.
    {
        Name (_ADR, One)
    }
}

Scope (\_SB.PCI0.PEX4)
{
    Device (FRWR) // Adding name for Firewire.
    {
        Name (_ADR, Zero)
    }
}

Scope (\_SB.PCI0.PEX5)
{
    Device (GIGE) // Adding name for Ethernet.
    {
        Name (_ADR, Zero)
    }
}

// The following lines were added to fix sleep, and without modifications to the DSDT.
// Note: This is only possible with RevoBoot v1.0.20 and greater, and RevoBoot only!

External (DBG8, IntObj)
External (\_SB.SMIC, IntObj)
External (\_SB.PCI0.SBRG.PS1S, IntObj)
External (\_SB.PCI0.SBRG.PS1E, IntObj)

Method (_PTS, 1, NotSerialized) // Prepare To Sleep
{
    Store (0x90, \_SB.SMIC)
    Store (Arg0, DBG8)

    If (LNotEqual (Arg0, 0x05))
    {
        Store (One, \_SB.PCI0.SBRG.PS1S)
        Store (One, \_SB.PCI0.SBRG.PS1E)
    }
}