Requêtes SPARQL

Liste des militants de la paix (https://en.wikipedia.org/wiki/List_of_peace_activists)

Requête 1 : Liste des activistes pour la paix

Cette requête SPARQL interroge DBpedia pour récupérer les relations (?p) et les ressources associées (?o1) liées à la ressource List_of_peace_activists. Elle filtre les résultats pour ne retenir que celles où ?o1 est une personne (a dbo:Person). La clause LIMIT 100 restreint le résultat à 100 entrées distinctes.

PREFIX dbr: <http://dbpedia.org/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
SELECT DISTINCT ?p ?o1 
WHERE { 
  dbr:List_of_peace_activists ?p ?o1.
  ?o1 a dbo:Person.
}
LIMIT 100

Requête 2 : Propriétés sortantes et effectifs

Cette requête SPARQL explore les relations (?p1) des personnes (?o1) associées à List_of_peace_activists sur DBpedia. Elle compte le nombre d'occurrences de chaque relation (?eff) grâce à COUNT(*), regroupe les résultats par type de relation (GROUP BY ?p1), et les trie par ordre décroissant d'occurrences (ORDER BY DESC(?eff)).

PREFIX dbr: <http://dbpedia.org/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
SELECT ?p1 (COUNT(*) as ?eff)
WHERE { 
dbr:List_of_peace_activists ?p ?o1.
?o1 a dbo:Person;
    ?p1 ?o2.
  }
GROUP BY ?p1
ORDER BY DESC(?eff)

Requête 3 : Liste des propriétés entrantes

Cette requête SPARQL examine les relations (?p1) reliant des personnes (?o1) associées à List_of_peace_activists, mais uniquement pour celles nées après 1800. Elle utilise dbo:birthDate pour extraire l'année de naissance (?birthYear) et filtre les résultats en conséquence. La requête compte le nombre d'occurrences pour chaque relation (?eff), regroupe par relation (GROUP BY ?p1), et trie les résultats par fréquence décroissante (ORDER BY DESC(?eff)).

PREFIX dbr: <http://dbpedia.org/resource/>
PREFIX dbo: <http://dbpedia.org/ontology/>
SELECT ?p1 (COUNT(*) as ?eff)
WHERE { 
    {
      {dbr:List_of_peace_activists ?p ?o1. }
    }
?o1 a dbo:Person;
dbo:birthDate ?birthDate.
?o2 ?p1 ?o1.
BIND(xsd:integer(SUBSTR(STR(?birthDate), 1, 4)) AS ?birthYear)
FILTER ( (?birthYear >= 1800  )) 
  }
GROUP BY ?p1
ORDER BY DESC(?eff)

Requête 4 : Liste de militant pour la paix de 1800 à nos jours

Cette requête SPARQL extrait les informations sur les personnes (?o1) associées à List_of_peace_activists sur DBpedia. Pour chaque personne, elle récupère leur nom (?label), transformé en chaîne (?name), et leur année de naissance (?birthYear), calculée à partir de dbo:birthDate. La requête filtre les résultats pour inclure uniquement les individus nés après 1800 et dont le label est en anglais (LANG(?label) = 'en'). Les résultats sont triés par année de naissance croissante (ORDER BY ?birthYear).

PREFIX dbr: <http://dbpedia.org/resource/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX dbo: <http://dbpedia.org/ontology/>
SELECT DISTINCT ?o1  (str(?label) as ?name) ?birthYear
WHERE {
SELECT DISTINCT ?o1 ?birthDate ?birthYear ?label
WHERE { 
    {
      {dbr:List_of_peace_activists ?p ?o1. }
    }
  ?o1 a dbo:Person;
    dbo:birthDate ?birthDate;
    rdfs:label ?label.
  BIND(xsd:integer(SUBSTR(STR(?birthDate), 1, 4)) AS ?birthYear)
  FILTER ( (?birthYear >= 1800
              )
              && LANG(?label) = 'en') 
        }
}
ORDER BY ?birthYear

Requête 5 : Liste des militants pour la paix avec des propriétés

Effectif de la liste (08.12.2024) : 80 personnes

Cette requête SPARQL extrait les informations sur les personnes (?o1) associées à List_of_peace_activists dans DBpedia, en incluant leur année de naissance (?birthYear). Elle vérifie que les individus sont des personnes (dbo:Person), récupère leurs professions (?target) avec un label en anglais, et calcule l'année de naissance (BIND) à partir de leur date de naissance (dbp:birthDate ou dbo:birthDate). La requête filtre pour inclure uniquement les personnes nées après 1800 et trie les résultats par année de naissance (ORDER BY ?birthYear).

PREFIX dbr: <http://dbpedia.org/resource/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX rdfs:<http://www.w3.org/2000/01/rdf-schema#>
SELECT DISTINCT (?o1 AS ?subject_uri) ?birthYear
#(COUNT(*) AS ?effectif) 
WHERE {
SELECT DISTINCT ?o1 ?birthYear ?target (str(?label) as ?name)
WHERE { 
    {
       {dbr:List_of_peace_activists ?p ?o1. }
    }
    ?o1 a dbo:Person;
    dbp:birthDate | dbo:birthDate ?birthDate;
    dbp:occupation | dbo:occupation ?target.
?target rdfs:label ?label.
BIND(xsd:integer(SUBSTR(STR(?birthDate), 1, 4)) AS ?birthYear)
    FILTER ( (?birthYear >= 1800   )  && LANG(?label) = 'en') # 
        }
ORDER BY ?birthYear
}

Requête 6 : Liste des militants pour la paix avec propriété "date de naissance"

Effectif de la liste (08.12.2024) : 369 personnes

Cette requête SPARQL identifie les personnes (?o1) associées à la ressource List_of_peace_activists sur DBpedia. Pour chaque personne, elle extrait leur nom (?label, converti en chaîne ?name) et leur année de naissance (?birthYear), calculée à partir de la propriété dbo:birthDate. La requête filtre les résultats pour inclure uniquement les personnes nées après 1800, avec un label en anglais (LANG(?label) = 'en')). Les résultats sont triés par ordre croissant d'année de naissance (ORDER BY ?birthYear).

PREFIX dbr: <http://dbpedia.org/resource/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX dbo: <http://dbpedia.org/ontology/>
SELECT DISTINCT ?o1  (str(?label) as ?name) ?birthYear
WHERE {
SELECT DISTINCT ?o1 ?birthDate ?birthYear ?label
WHERE { 
  {
        {dbr:List_of_peace_activists ?p ?o1. }
  }
  ?o1 a dbo:Person;
    dbo:birthDate ?birthDate;
    rdfs:label ?label.
  BIND(xsd:integer(SUBSTR(STR(?birthDate), 1, 4)) AS ?birthYear)
  FILTER ( (?birthYear >= 1800
  #            && ?birthYear < 2000
              )
              && LANG(?label) = 'en') 
        }
}
ORDER BY ?birthYear