1-1. ArduinoCloud를 활용한 온습도&LED 센서 실습 및 NTP 서버로 시간 정보 확인

2-1. Arduino에서 제공하는 IoT 클라우드로 온습도 데이터를 실시간 모나터링과 외부 LED 제어하는 실습에서 사용
2-2. 실습 준비물: ESP32, ESP32 확장 실드, DH11 온습도 센서, LED 모듈, 점퍼 케이블
2-3. ArduinoCloud 설정 및 실행코드

#include "thingProperties.h"
#include "DHT.h"

int led_pin = 23;
int dh11_pin = 13;

DHT dht(dh11_pin, DHT11);

void setup() {
  pinMode(led_pin, OUTPUT);
  dht.begin();
  // Initialize serial and wait for port to open:
  Serial.begin(9600);
  // This delay gives the chance to wait for a Serial Monitor without blocking if none is found
  delay(1500);

  // Defined in thingProperties.h
  initProperties();

  // Connect to Arduino IoT Cloud
  ArduinoCloud.begin(ArduinoIoTPreferredConnection);

  setDebugMessageLevel(2);
  ArduinoCloud.printDebugInfo();
}

void loop() {
  ArduinoCloud.update();
  // Your code here
  // Read temperature as Celsius (the default)
  temperature = dht.readTemperature();

  // Check if any reads failed and exit early (to try again).
  if (isnan(temperature)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  Serial.print(F("Temperature: "));
  Serial.println(temperature);

  delay(1000);
}

void onLedStateChange() {
  // Add your code here to act upon LedState change
  Serial.print("LED state is changed : ");
  Serial.println(led_state);
  if (led_state) {
    digitalWrite(led_pin, HIGH);
  } else {
    digitalWrite(led_pin, LOW);
  }
}

3-1. 의미: 네트워크를 통해 컴퓨터 시스템 간의 시간을 동기화하는 프로토콜로 인터넷과 로컬 네트워크에서 사용
     - 서버와 클라이언트 간의 시간 정보를 주고 받아 시간을 동기화시킴
     - 정밀한 원자 시계 또는 GPS를 통해 정확한 시간을 유지함
     - 클라이언트는 주기적으로 NTP 서버에 접속하여 시간 정보를 갱신함
3-2. NTP 계층 구조
     - Stratum 0: 원자 시계, GPS 등 절대 시간을 제공하는 장치
     - Stratum 1: Stratum 0 장치와 직접 연결된 NTP 서버
     - Stratum 2: Stratum 1 서버와 동기화된 서버들
     - Stratum 2~15: NTP 서버를 경유할 때 마다 Stratum 1씩 증가하며 Stratum 2부터는 계층적 트리 구조를 형성함

3-3. NTP 서버에서 시간을 가져와 OLED 디스플레이에 표시하는 실습
     - 실습 준비물: ESP32, ESP32 확장 실드, OLED 디스플레이, 점퍼 케이블
     - Adafruit SSD1306 라이브러리 설치(Adafruit GFX 라이브러리 포함하여 전체 설치)

#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 32

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

void setup() {
    Serial.begin(9600);

    // OLED 디스플레이 초기화
    if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
        Serial.println("SSD1306 오류");
        while (true);
    }

    // OLED 디스플레이 클리어
    display.clearDisplay();
}

void loop() {
    // "Hello, World!"를 크기가 다른 두 개의 텍스트로 표시
    display.clearDisplay();
    
    // 크기 6의 폰트로 텍스트 표시
    display.setTextSize(1);
    display.setTextColor(WHITE);
    display.setCursor(0, 0);
    display.println("Hello, World!");

    // 크기 8의 폰트로 텍스트 표시
    display.setTextSize(2);
    display.setTextColor(WHITE);
    display.setCursor(0, 15);
    display.println("Hello, World");

    display.display();
    delay(2000);
}

#include <WiFi.h>  // WiFi 통신을 위한 라이브러리
#include <time.h>  // 시간과 관련된 함수를 위한 라이브러리

#include <Adafruit_GFX.h>      // 디스플레이를 위한 그래픽 라이브러리
#include <Adafruit_SSD1306.h>  // SSD1306 OLED 디스플레이를 위한 라이브러리
// SSD1306 디스플레이 객체 초기화
Adafruit_SSD1306 display = Adafruit_SSD1306(128, 32, &Wire, -1);

const char* ssid = "zineeh";          // 여기에 사용하는 WiFi 네트워크 이름 (SSID)을 입력하세요
const char* password = "SMARTDEVICE0527";  // 여기에 사용하는 WiFi 네트워크 비밀번호를 입력하세요

int GMTOffset = 60 * 60 * 9;  // 시간 오프셋 설정, 한국은 UTC/GMT +9입니다.
int daylightOffset = 0;       // 국가에서 서머타임을 사용하는 경우 오프셋 값을 설정하세요.

const String weekDays[7] = { "Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat" };  // 요일 이름 배열

void setup() {
  Serial.begin(115200);  // 디버깅을 위한 시리얼 통신 시작

  // SSD1306 디스플레이 초기화
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 초기화 실패"));
    while (1)
      ;  // 디스플레이 초기화에 실패하면 프로그램 실행 중지
  }

  delay(2000);                  // 2초 동안 대기
  display.clearDisplay();       // 디스플레이 지우기
  display.setTextSize(1);       // 텍스트 크기를 1로 설정
  display.setCursor(0, 0);      // 커서 위치를 디스플레이 왼쪽 위 모서리로 설정
  display.setTextColor(WHITE);  // 텍스트 색상을 흰색으로 설정

  WiFi.begin(ssid, password);  // 제공된 SSID와 비밀번호를 사용하여 WiFi 네트워크에 연결
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting...");
  }

  Serial.println("Connected to Wi-Fi!");
  // 시간 설정을 위한 NTP 서버 설정
  configTime(GMTOffset, daylightOffset, "pool.ntp.org", "time.nist.gov");
}


void loop() {

  // 현재 시간 가져오기
  time_t rawtime = time(nullptr);
  struct tm* timeinfo = localtime(&rawtime);

  // 시리얼 모니터에 날짜 출력
  Serial.print(timeinfo->tm_mday);
  Serial.print("/");
  Serial.print(timeinfo->tm_mon + 1);
  Serial.print("/");
  Serial.print(timeinfo->tm_year + 1900);

  Serial.print(" ");

  // 시리얼 모니터에 시간 출력
  Serial.print("Time: ");
  Serial.print(timeinfo->tm_hour);
  Serial.print(":");
  Serial.print(timeinfo->tm_min);
  Serial.print(":");
  Serial.println(timeinfo->tm_sec);

  // OLED 디스플레이 초기화
  display.clearDisplay();
  display.setTextSize(3);
  display.setTextColor(WHITE);
  display.setCursor(0, 0);

  // 시간 출력
  if (timeinfo->tm_hour < 10)
    display.print("0");
  display.print(timeinfo->tm_hour);

  display.print(":");

  if (timeinfo->tm_min < 10)
    display.print("0");
  display.print(timeinfo->tm_min);

  display.print(":");

  // 초 출력
  display.setTextSize(2);
  display.setCursor(102, 5);

  if (timeinfo->tm_sec < 10)
    display.print("0");
  display.print(timeinfo->tm_sec);

  // 날짜 출력
  display.setTextSize(1);
  display.setCursor(0, 25);
  display.print(timeinfo->tm_mday);
  display.print("/");
  display.print(timeinfo->tm_mon + 1);
  display.print("/");
  display.print(timeinfo->tm_year + 1900);

  display.print(" ");
  display.print(weekDays[timeinfo->tm_wday]);

  // 디스플레이에 표시
  display.display();

  delay(1000);
}

4-1. 직렬버스이며 마더보드, 임베디드 시스템, 휴대 전화 등에 저속 기기를 연결할 때 사용됨
     - 풀업 저항이 연결된 직렬 데이터와 직렬 클럭이라는 두개의 양방향 오픈 컬렉터 라인 사용
     - 최대 전압은 +5V이지만 일반적으로 +3.3V 시스템 사용
     - I²C 레퍼런스 디자인은 7비트의 주소 공간을 가지며 동일한 버스에 최대 112개의 노드가 연결 가능함
     - 빠른 속도를 필요로 하지 않는 간단한 저비용 장치에 적합
     - 휴대전화 같은 장치에 포함된 발광 다이오드를 제어하는 경우, 하드웨어 모니터링과 진단 센서 정보를 읽는 경우, 실시간 클럭을 읽는 경우, 시스템 요소의 전원을 제어하는 경우
4-2. 장점
     - SDA와 SCL 두가닥의 선만으로 데이터 송수신이 가능함
     - 동기식 통신이므로 비동기식 통신(UART)에 비해 다소 안정적임
     - 버스 형태로 한개의 I²C 마스터에 다수의 슬레이브 장치 연결 가능
     - 데이터를 전송/수신 활동은 마스터에서 주도하며 데이터 송수신시 슬레이브 주소를 마스터에 명시해야 통신이 가능
4-3. 단점
     - 비동기식 통신(UART)보다 빠르지만 SPI에 비교하면 느림
     - 반이중 통신으로 한쪽에서 데이터를 보낼 때 반대편에서 데이터 전송 불가
     - 구조상 복잡하여 사용하기 어렵고 전송을 위한 별도의 회로를 구성해야 함

5-1. Floating Point Number(부동 소수점 수): 매우 크거나 작은 수치를 지수와 가수 부분으로 나누어 표현
     - 소수점 표현, 아주 작은 수 표현, 아주 큰 수 표현
5-2. Adafruit: 오픈소스형 전자 하드웨어의 설계 및 생산을 전문으로 하는 비공개기업으로 미국 본사에서 제품을 설계 및 생산
     - OLED 디스플레이 실습에서 사용하며 OLED 제어를 위해 Adafruit_SSD1306 라이브러리 설치와 객체 선언 필요
5-3. OLED 디스플레이 실습에서 발생하는 네트워크 연결 오류(아이폰): 개인 핫스팟 연결 후 호환성 최대화가 활성화되어 있는지 확인
     - 호환성 최대화를 활성화시킨 후 오류가 해결되어 시간이 디스플레이에 표시되었지만 정확한 해결방안인지 모름