/
types.asm
92 lines (76 loc) · 1.28 KB
/
types.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
PrintMonTypes:
; Print one or both types of [wCurSpecies]
; on the stats screen at hl.
push hl
call GetBaseData
pop hl
push hl
ld a, [wBaseType1]
call .Print
; Single-typed monsters really
; have two of the same type.
ld a, [wBaseType1]
ld b, a
ld a, [wBaseType2]
cp b
pop hl
jr z, .hide_type_2
ld bc, SCREEN_WIDTH
add hl, bc
.Print:
ld b, a
jr PrintType
.hide_type_2
; Erase any type name that was here before.
; Seems to be pointless in localized versions.
ld a, " "
ld bc, SCREEN_WIDTH - 3
add hl, bc
ld [hl], a
inc bc
add hl, bc
ld bc, NAME_LENGTH_JAPANESE - 1
jp ByteFill
PrintMoveType:
; Print the type of move b at hl.
push hl
ld a, b
dec a
ld bc, MOVE_LENGTH
ld hl, Moves
call AddNTimes
ld de, wStringBuffer1
ld a, BANK(Moves)
call FarCopyBytes
ld a, [wStringBuffer1 + MOVE_TYPE]
pop hl
ld b, a
PrintType:
; Print type b at hl.
ld a, b
push hl
add a
ld hl, TypeNames
ld e, a
ld d, 0
add hl, de
ld a, [hli]
ld e, a
ld d, [hl]
pop hl
jp PlaceString
GetTypeName:
; Copy the name of type [wNamedObjectIndex] to wStringBuffer1.
ld a, [wNamedObjectIndex]
ld hl, TypeNames
ld e, a
ld d, 0
add hl, de
add hl, de
ld a, [hli]
ld h, [hl]
ld l, a
ld de, wStringBuffer1
ld bc, MOVE_NAME_LENGTH
jp CopyBytes
INCLUDE "data/types/names.asm"